訪問者を記録するスクリプト

今回は訪問者を記録するスクリプトです。
接触を調べて記録するようにしましたので、玄関マットやウェルカムマットなどに入れて使ってくださいね＾＾

オーナーがタッチすると訪問者リストを表示します。
同じアバターは最終訪問時間だけ残るようにしました。


リストは "時間","アバター名" のように記録してるので×２や÷２して調整してます＾＾；
５０人記録するようにしましたが、あまり増やし過ぎるとリストが長くなったときにメモリエラー出てスクリプト止まります。Monoでコンパイルしたらかなり余裕でますけど、ダーッとたくさん表示されても見るの大変だと思うんですねｗ
// 訪問者を記録
integer max=50;  // 最大記録件数
list visitor;  // 来訪時刻とビジター記録用リスト

string get_time()
{
    integer t=(integer)llGetWallclock();  // 太平洋時間
    integer h=t/3600;  // 時
    integer m=(t%3600)/60;  // 分
    string hh=(string)h;  // 「時」を文字に変換
    if (h < 10) hh="0"+hh;  // 「時」が１桁だったら0を付ける
    string mm=(string)m;
    if (m < 10) mm="0"+mm;
    return hh+":"+mm;  // hh:mm でリターン
}

save_visitor(string name)
{
    integer i=llListFindList(visitor,[name]);  // リストから名前をサーチ
    if (i > -1) {  // リストに名前があったら
        visitor=llDeleteSubList(visitor,i-1,i);  // 時間と名前を削除
    }
    visitor+=[get_time(),name];  // リストに時間と名前を登録
    integer j=llGetListLength(visitor);  // リストの長さ
    if (j > max*2) {  // リストが最大記録数×２を超えたら
        visitor=llDeleteSubList(visitor,0,j-1-max*2);  // 古いほうから消す
    }
}

default
{
    collision_start(integer num)
    {  // 接触したら
        string name=llDetectedName(0);  // アバター名取得
        save_visitor(name);  // save_visitorへ
    }

    touch_start(integer total_number)
    {  // タッチ
        key agent=llDetectedKey(0);  // アバターのキー
        if (agent == llGetOwner()) {  // オーナーなら
            integer i;
            integer j=llGetListLength(visitor);  // リストの長さ
            llOwnerSay((string)(j/2)+" visitor(s).");  // 訪問者数表示
            for (i=0; i < j; i+=2) {  // リストから２つずつ読み出し（時間と名前）
                llOwnerSay(llList2String(visitor,i)+" "+llList2String(visitor,i+1));
            }
        }
    }
}

２００９年３月１８日２３時２5分頃追記：　コメント頂きましたリストの長さ調整の部分の間違いを直しました。

２００９年７月２日追記：　リストの長さ調整ですが、llDeleteSubListよりllList2Listを使ったほうが感覚的にわかりやすそうなので、新しく作る製品にはllList2Listを使うようになりました。
visitor=llList2List(visitor,-max*2,-1);