郵便ポストのスクリプト

今回はノートをドロップしたらオーナーに送るポストって感じのスクリプトを書いてみました＾＾

オーナー以外もコンテンツにアイテムを入れられるようにするにはllAllowInventoryDropですね。

まずはご意見、アンケート、提案などを入れられる簡単な投書箱です。
// 投書箱
default
{
    state_entry()
    {
        llAllowInventoryDrop(TRUE);  // インベントリーにドロップ許可
    }

    changed(integer change)
    {
        if (change & CHANGED_ALLOWED_DROP)
        {  // オーナー以外が入れたとき
            llWhisper(0,"Thank you for your suggestion.");
            llInstantMessage(llGetOwner(),"Got a suggestion.");
        }
    }
}

これはノートは中に蓄積して、オーナー以外がノート入れたときにオーナーにIMで知らせます。
入ったものは特にチェックしてないのでノート以外も入れられますけどね＾＾；

CHANGED_ALLOWED_DROPはオーナー以外がコンテンツに変化を与えたときしか反応しないので、オーナーが自分でノート入れたときは返事ありませんｗ
なので、オーナーが入れたときも反応させたいときはCHANGED_INVENTORYと一緒に使ってくださいね。


そして、ポストのスクリプトです。ただ、SLのサーバーなどが調子良くないときは通販とかネットワークド・ベンダーと同じで届かないことがあるかもです＾＾；
// ポスト（このスクリプトは実用には向いてません＾＾；）
default
{
    state_entry()
    {
        llAllowInventoryDrop(TRUE);  // インベントリーにドロップ許可
    }

    touch_start(integer total_number)
    {  // タッチしたら
        llWhisper(0,"Put your notecard for owner."); // オーナー宛のノートちょーだい＾＾
    }

    changed(integer change)
    {
        if (change & (CHANGED_INVENTORY|CHANGED_ALLOWED_DROP))
        {  // ドロップされたら
            llAllowInventoryDrop(FALSE);  // ドロップを不許可にしといて
            string str;
            integer note=FALSE;  // ノートの有無チェック用フラグ
            integer i;
            for (i=0; i < llGetInventoryNumber(INVENTORY_ALL); i++)
            {  // アイテムを１個ずつチェック
                str=llGetInventoryName(INVENTORY_ALL,i);
                if (llGetInventoryType(str) == INVENTORY_NOTECARD)
                {  // ノートだったらオーナーに配送
                    llGiveInventory(llGetOwner(),str);
                    llWhisper(0,"Sent "+str);
                    note=TRUE;  // フラグをTRUE
                }
                if (llGetInventoryType(str) != INVENTORY_NONE) {
                    if (str != llGetScriptName()) {  // このスクリプト以外は削除
                        llRemoveInventory(str);
                        i--;
                    }
                }
            }
            llAllowInventoryDrop(TRUE);  // ドロップ許可
            // ノートを受付けたときのメッセージ
            if (note) llWhisper(0,"Thank you for your notecard.");
        }
    }
}


２０１０年５月４日追記：　ログインしてないときに届いたＩＭやアイテムなどの受け取れる数は上限が２５でした。なのでこのポストのスクリプトは実用上問題ありますね＾＾；　ノートを削除せずに蓄積していくようにしたほうが安心だと思います。