飛ぶと羽ばたくウイングのスクリプト

今回はアバターが飛行中のとき羽ばたくウイングのスクリプトです＾＾

羽のプリムは開き戸とかのドアと同じでパスカットして中心から半分だけになるようにします。なので、羽のテクスチャは片側ずつじゃなくて、左右くっついたものを１枚作ったらいいですね＾＾
編集でパスカットのBを0.375、Eを0.875にして、X方向のサイズを0.01くらいに薄くしてください。それで面番号１と３が羽の表面になるので、そこに作った羽のテクスチャを貼り付けて、その他の薄い面には透明のテクスチャを貼ります。
これを右用と左用で２枚作ります。そして、親プリムのサイズ X,Y,Z を 0.1,0.1,0.1 ぐらいで作って、右側の羽の角度X,Y,Zは 90,0,75、左側の羽は角度 90,0,285にして親プリムにリンクさせます。位置は親プリムより少し上になるようにテキトーに調整してくださいね。




アバターが飛んでるときは羽の角度が１５～７５度で羽ばたいて、飛んでないときは角度が１０度で固定になるようにしました。チョウチョが止まって羽をたたんだときみたいな感じですかね＾＾
// 飛んだとき羽ばたくウイング（親プリム用）
float angle;

default
{
    attach(key on)
    {  // 装着されたときは１秒ごとにタイマー
        if (on) llSetTimerEvent(1.0);
        else llSetTimerEvent(0);
    }

    timer()
    {
        if (llGetAgentInfo(llGetOwner()) & AGENT_FLYING)
        { // 飛んでるとき
            if (angle < 45) angle=75;  // 角度が４５度までだったら７５度に設定
            else angle=15;  // そうじゃないときは１５度に設定
            llMessageLinked(LINK_ALL_CHILDREN, 0, (string)angle, "");  // 子プリムに角度を送信
        }
        else {  // 飛んでないとき
            if (angle != 10) {  // 角度が１０度じゃなかったら
                angle=10;  // １０度に設定
                llMessageLinked(LINK_ALL_CHILDREN, 0, (string)angle, "");  // 子プリムに角度を送信
            }
        }
    }
}

// 飛んだとき羽ばたくウイング（右側の羽）
default
{
    link_message(integer sender_num, integer num, string msg, key id)
    {  // リンクメッセージ受信したら角度を設定
        llSetLocalRot(llEuler2Rot(<90,0,(float)msg>*DEG_TO_RAD));
    }
}

// 飛んだとき羽ばたくウイング（左側の羽）
default
{
    link_message(integer sender_num, integer num, string msg, key id)
    {  // リンクメッセージ受信したら角度を設定（こっちの角度はマイナスに）
        llSetLocalRot(llEuler2Rot(<90,0,-(float)msg>*DEG_TO_RAD));
    }
}